Gecko [ www.corporacionhdm.com.pe ]

Name	Size	Permission	Date
Makefile.global	6.86 KB	-rw-r--r--	2025-03-12 13:18
ax_check_compile_flag.m4	2.06 KB	-rw-r--r--	2025-03-12 13:18
ax_gcc_func_attribute.m4	8.21 KB	-rw-r--r--	2025-03-12 13:18
config.guess	49.55 KB	-rwxr-xr-x	2025-03-12 13:18
config.sub	38.78 KB	-rwxr-xr-x	2025-03-12 13:18
gen_stub.php	217.97 KB	-rw-r--r--	2025-03-12 13:18
libtool.m4	323.83 KB	-rw-r--r--	2025-03-12 13:18
ltmain.sh	316.55 KB	-rw-r--r--	2025-03-12 13:18
php.m4	72.94 KB	-rw-r--r--	2025-03-12 13:18
php_cxx_compile_stdcxx.m4	18.19 KB	-rw-r--r--	2025-03-12 13:18
phpize.m4	5 KB	-rw-r--r--	2025-03-12 13:18
pkg.m4	10.01 KB	-rw-r--r--	2025-03-12 13:18
run-tests.php	138.82 KB	-rw-r--r--	2025-03-12 13:18
shtool	64.22 KB	-rwxr-xr-x	2025-03-12 13:18

Rename

# ===========================================================================
#  https://www.gnu.org/software/autoconf-archive/ax_check_compile_flag.html
# ===========================================================================
#
# SYNOPSIS
#
#   AX_CHECK_COMPILE_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS], [INPUT])
#
# DESCRIPTION
#
#   Check whether the given FLAG works with the current language's compiler
#   or gives an error.  (Warnings, however, are ignored)
#
#   ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
#   success/failure.
#
#   If EXTRA-FLAGS is defined, it is added to the current language's default
#   flags (e.g. CFLAGS) when the check is done.  The check is thus made with
#   the flags: "CFLAGS EXTRA-FLAGS FLAG".  This can for example be used to
#   force the compiler to issue an error when a bad flag is given.
#
#   INPUT gives an alternative input source to AC_COMPILE_IFELSE.
#
#   NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
#   macro in sync with AX_CHECK_{PREPROC,LINK}_FLAG.
#
# LICENSE
#
#   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
#   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
#
#   Copying and distribution of this file, with or without modification, are
#   permitted in any medium without royalty provided the copyright notice
#   and this notice are preserved.  This file is offered as-is, without any
#   warranty.

#serial 7

AC_DEFUN([AX_CHECK_COMPILE_FLAG],
[AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_IF
AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_[]_AC_LANG_ABBREV[]flags_$4_$1])dnl
AC_CACHE_CHECK([whether the _AC_LANG compiler accepts $1], CACHEVAR, [
  ax_check_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
  _AC_LANG_PREFIX[]FLAGS="$[]_AC_LANG_PREFIX[]FLAGS $4 $1"
  AC_COMPILE_IFELSE([m4_default([$5],[AC_LANG_PROGRAM()])],
    [AS_VAR_SET(CACHEVAR,[yes])],
    [AS_VAR_SET(CACHEVAR,[no])])
  _AC_LANG_PREFIX[]FLAGS=$ax_check_save_flags])
AS_VAR_IF(CACHEVAR,yes,
  [m4_default([$2], :)],
  [m4_default([$3], :)])
AS_VAR_POPDEF([CACHEVAR])dnl
])dnl AX_CHECK_COMPILE_FLAGS